start tok64 d64-OCKQFx
0 POKE650,128:POKE53280,.:POKE53281,.:PRINT"{clear}{ct h}{142}":REM"{home}{ct y}{home}
1 a$="{home}{space*2}{cm a}{cm s}{space*2}{cm a}{cm s}{space*8}{cm a}{cm s}{space*5}{cm a}{sh asterisk}{cm r*2}{cm s}{space*2}{green}{pound}versatt
2 b$="{space*2}{sh -}{cm q}{cm r}{sh asterisk}{cm w}{cm q}{cm s}{cm a}{sh asterisk*2}{cm r}{sh asterisk}{cm r}{sh asterisk}{cm w}{cm z}{cm r}{sh asterisk}{cm r}{sh asterisk}{cm s}{sh -}{sh asterisk}{cm w}{sh -*2}{space*2}{green}av {white}mr.p.
3 c$=" {cm a}{cm x}{cm q}{cm w}{sh asterisk}{cm w}{sh -*5}{cm q}{sh asterisk}{sh -}{sh asterisk}{cm w}{cm a}{cm w}{sh -*2}{cm q}{cm x}{sh -*2}{cm q}{cm s}{sh -}{space*2}{green}{space*3}of
4 d$=" {sh -*3}{cm q}{sh asterisk}{sh -} {cm w}{sh -*4}{sh asterisk}{cm q}{sh asterisk}{sh -}{cm q}{cm w}{cm a}{cm w}{sh -} {sh -*5} {blue}soft{yellow}wolves
5 e$=" {cm z}{sh asterisk}{cm e*2}{sh asterisk}{cm e*2}{cm x}{cm z}{cm e*3}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{cm x} {cm z}{sh asterisk}{cm x}{cm z}{cm x} {green} f{pound}r sys!
6 x$="{dark gray}{gray}{light gray}{white}{light gray}{gray}{dark gray}{black}":FORi=.TO17
7 PRINTLEFT$(x$,1)a$:PRINTMID$(x$,2,1)b$:PRINTMID$(x$,3,1)c$:PRINTMID$(x$,4,1)d$
8 PRINTMID$(x$,5,1)e$
9 x$=MID$(x$,2)+LEFT$(x$,1):NEXT
10 PRINT"{down*3}{gray}ok. att kopiera, men {white}inte att s[lja
20 PRINT"{down*3}{gray}f{pound}rb[ttrat av fritz oppliger
21 PRINT"{down}{pound}versatt av mr.p. f{pound}r sys
30 s=54272:FORl=sTOs+24:POKEl,.:NEXT
31 POKEs+24,15:POKEs+5,8:POKEs+6,255:POKEs+4,23
32 FORa=1TO2:lf=10:FORb=1TO6:hf=10:POKEs+1,lf:FORc=1TO4:POKEs+15,hf:hf=hf*1.02
33 NEXT:lf=lf*1.2:NEXT:FORd=1TO8:hf=20:POKEs+1,hf:FORe=1TO3:POKEs+15,hf
34 hf=hf*1.2:NEXT:lf=lf/1.2:NEXT:NEXT:POKEs+4,.
40 GOTO8640
120 PRINT"{clear}{down*24}{black} {pound}vers[ttning+logo av: mr.p. f{pound}r sys pd{home}";
121 PRINT"{black}{right}{blue}{reverse on}{space*2}{cm t*2}{cm y*2}{black} {cm a}{cm r*2}{sh asterisk}{cm r*2}{cm s}{cm a}{sh asterisk*2}{cm r}{sh asterisk}{cm r}{sh asterisk}{cm r}{cm s}{cm a}{sh asterisk}{cm r}{sh asterisk}{cm r}{sh asterisk}{cm r*2}{cm s}{yellow}{cm y*2}{cm t*2}{space*2}"
122 PRINT"{black}N{blue}{reverse on}{cm d*2}{cm p*2}{cm @*2}{black}{cm a}{cm x}{cm q}{cm w}{sh asterisk}{cm w}{sh -*5}{cm q}{sh asterisk}{sh -}{sh asterisk}{cm w}{cm z}{cm w}{sh -*2}{cm q}{cm w}{sh asterisk}{cm w}{sh -*2}{yellow}{cm @*2}{cm p*2}{cm d*2}{black}{reverse off}M";
140 PRINT"M{yellow}{reverse on}{cm u*2}{cm y*2}{cm t*2}{black}{sh -*3}{cm q}{sh asterisk}{sh -} {cm w}{sh -*4}{sh asterisk}{cm q}{sh asterisk}{sh -}{cm a}{cm w}{cm a}{cm w}{sh -*3}{cm q}{cm s}{sh -}{blue}{cm t*2}{cm y*2}{cm u*2}{black}{reverse off}N";
160 PRINT"{right}{yellow}{reverse on}{space*2}{cm @*2}{cm p*2}{black}{cm z}{sh asterisk}{cm e*2}{sh asterisk}{cm e*2}{cm x}{cm z}{cm e*3}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{cm x}{cm z}{sh asterisk}{cm x}{cm z}{cm x}{blue}{cm p*2}{cm @*2}{space*2}{black}":RETURN
180  
200  
220 REM   c-64 / single 1541
240  
260  
280 REM improved by
300 REM   fritz oppliger
320 REM   pobox 1187
340 REM   redway ca 95560
345 REM svensk verision och ny logo av
357 REM softwolves f{pound}r
359 REM sys pd 1991
360  
380 REM   thanks to
400 REM      r w baker
420 REM      m contino
440  
460 REM   ok to copy but not to sell
480  
500  
520 CLOSE5:CLOSE4:cx=0:pd=3:c$=""
540 POKE53280,15:GOSUB1000:GOSUB120
560 v$(0)="{yellow}>{black} lista diskarnas {blue} namn och id {black}{space*6}{yellow}<{black}
580 v$(1)="{yellow}>{black} visa{blue} valt directory {black}{space*15}{yellow}<{black}
600 v$(3)="{yellow}>{black} hitta{blue} specifierad fil {black}{space*13}{yellow}<{black}
620 v$(4)="{yellow}>{blue} katalogisera {black}en diskett{space*12}{yellow}<{black}
640 v$(5)="{yellow}>{blue} radera {black}diskett fr]n master{space*9}{yellow}<{black}
660 v$(6)="{yellow}>{black}{space*2}lista{blue} min {black}fria block p] diskett{space*3}{yellow}<{black}
680 v$(7)="{yellow}>{black}{space*2}lista{blue} max {black}fria block p] diskett{space*3}{yellow}<{black}
700 v$(8)="{yellow}>{black}{space*3}snabblista {pound}ver{blue} an[nda idkoder {black}{space*2}{yellow}<{black}
720 v$(9)="{yellow}>{black}{space*3}printa fullst[ndig id-kods{blue} lista {yellow}<{black}
730 v$(2)="{yellow}>{black} visa{blue} diskettens directory {black}{space*9}{yellow}<{black}
740 v$(10)="{yellow}>{white}{space*3}{red}{space*2}{white} ]ter {black}till basic{space*15}{yellow}<"
750 PRINT" -=-=-=-=-=-=- huvud-meny -=-=-=-=-=-=-
760 PRINT"{down*12}{space*8}UD{red}{reverse on}{sh pound}{cm asterisk}{reverse off}{black}{D*5}I{space*10}U{D*8}I"
780 PRINT" anv[nd G {red}cursor{black} H{space*3}och{space*4}G {red}return{black} H"
800 PRINT"{space*8}J{F*5}{red}{cm asterisk}{sh pound}{black}FK{space*10}J{F*8}K"
820 np=10:GOSUB8940
840  
860 REM      branching...
880  
900 ONv GOTO5340,3520,10000,1140,1960,4300,7320,7480,5060,4580,7000
960 REM     sound
980  
1000 s=54272:FORl=sTOs+24:POKEl,.:NEXT
1020 POKEs+24,15:POKEs+1,20:POKEs,136:POKEs+3,4:POKEs+2,.:POKEs+5,8:POKEs+6,248
1040 POKEs+15,75:POKEs+4,67:FORi=1TO25:POKEs+15,120-4*i:NEXT:POKEs+4,64
1060 RETURN
1080  
1100 REM    specified {233}ile...
1120  
1140 IFnx=0THENGOSUB5720:GOTO520
1160 CLOSE4:PRINT"{clear}finn vilken disk/etter som fil finns p]":PRINT
1180 PRINT"v[lj filnamn ":PRINT:PRINT"(f{pound}rsta tecknen;'*'beh{pound}vs ej)":PRINT
1200 INPUTf$:IFf$=""THEN520
1220 IFf$="*"THENPRINT:GOTO1180
1240 s$=f$:GOSUB6000:v=y:GOSUB6100
1260 OPEN4,pd:PRINT#4,"{reverse on}{light blue} filnamn {.*8} id, disk namn {.*8}{black}":PRINT#4
1280 IFst<>.THENGOSUB8220:GOTO520
1300 PRINT#4,s$:q$=LEFT$(s$,1):PRINT#4
1320 POKEad-1,ASC(q$):POKEgin+27,192:REM modify ml
1340 FORz=.TOnx-1:di$=LEFT$(x$(z),2):dn$=MID$(x$(z),3)
1360 s$="0:dir."+di$
1380 PRINT"{blue}{space*8}U{C*9}{cm r}CCI{space*3}U{D*4}I{space*7}"
1400 PRINT"{reverse on}{blue}{space*2}l[ser {reverse off}{cm k}{black}"LEFT$(dn$,9)"{blue}B{black}"di$"{blue}B{space*3}B{red} {arrow left}{blue} {cm asterisk}{reverse on}avslutar{reverse off}"
1420 PRINT"{blue}{space*8}J{C*9}{cm e}CCK{space*3}J{F*4}K{space*7}"
1440 GOSUB9420:PRINT"{up*3}";
1460 OPEN5,8,5,"0:dir."+di$+",s,r":ef=15
1480 INPUT#5,df$,nb
1500 IFPEEK(q)>.THENGOSUB1000:GOTO1840
1520 SYSad
1540 IFPEEK(q)>.THENGOSUB1000:GOTO1840
1560 s$=CHR$(PEEK(ad-2)):POKEgin+28,18:SYSgin:s$=s$+LEFT$(in$,15):POKEgin+28,20
1620 ss=st:INPUT#15,en,em$:IFen>.THENGOSUB6520:GOTO8140
1640 IFf$<LEFT$(s$,v)THEN1720
1660 IFf$=LEFT$(s$,v)THENPRINT#4,s$;"{space*2}";di$;"{space*2}";dn$
1680 IFss>.THEN1720
1700 SYSgin:s$=MID$(in$,2,16):GOTO1620
1720 CLOSE5:NEXTz
1740 GOSUB6520
1760 IFpd=4THEN520
1780 GOSUB9700
1800 GOSUB6260
1820 GOTO520
1840 GETc$:IFc$="{arrow left}"THENPOKEq,.:GOTO1720
1860 IFc$="q"THENCLOSE5:GOSUB6520:GOTO520
1880 PRINT"{red}Q{left}{blue}";:FORx=.TO99:NEXT:WAIT197,64,64:GOSUB1000:PRINT" {left}";:
1900 FORx=.TO99:NEXTx:POKEq,.:GOTO1520
1920  
1940 REM    updating...
1960  
1980 CLOSE15:cx=0:POKE53280,14
2000 me$="s[tt i disk att katalogisera"
2020 GOSUB8280
2040 IFc$="q"THENGOSUB7100:GOTO520
2060 GOSUB6480:PRINT"ok":OPEN15,8,15,"i0"
2080 IFst<>.THEN8140
2100 OPEN5,8,5,"$0"
2120 SYSgin
2140 GOSUB8120
2160 dn$=MID$(in$,143,16)
2180 di$=MID$(in$,161,2)
2200 di$=LEFT$(di$+"{space*2}",2)
2220 PRINT"{clear}{down*3}{reverse on}{blue}{space*2}diskens namn,id:{black}{reverse off} "dn$", "di$:PRINT
2240 nb=0 :REM bam
2260 FORz=3TO141STEP4:c$=MID$(in$,z,1):v=ASC(c$)
2280 IFz=71THENNEXTz
2300 nb=nb+v
2320 NEXT
2340 IFnx=0THEN2640
2360 FORx=0TOnx-1:c$=LEFT$(x$(x),2)
2380 IFdi$<c$THEN2640
2400 IFdi$<>c$THENNEXTx:GOTO2640
2420 IFdn$=MID$(x$(x),3)THEN2640
2440 PRINT"{clear}{down*2}"SPC(10)"*{space*2}varning{space*2}*":PRINT:PRINT"diskens idkod: {reverse on}";di$;"{reverse off}"
2460 PRINT:PRINT"disknamn : {reverse on}";dn$
2480 PRINT:PRINT"finns redan i registret med ett annat "
2500 PRINT:PRINT"disknamn : {reverse on}";MID$(x$(x),3):PRINT
2520 GOSUB6480
2540 PRINT"registrering av disken tar bort
2560 PRINT:PRINT"tidigare data"
2580 GOSUB6480:PRINT
2600 INPUT"registrera disken? j{left*3}";c$:IFc$<>"j"THENGOSUB7100:GOTO3420
2620 PRINT"{clear}{down*3}{space*4}registrera disken med nytt namn":PRINT
2640 PRINT"l[ser inneh]llsf{pound}rteckning..":PRINT
2660 df$=MID$(in$,164,2)
2680 nf=0:z=0
2700 se=18
2720 se=se-1:SYSgin
2740 j=257:z=32
2760 j=j-z:a=.:v=.:l=.
2780 f$=MID$(in$,j,1):a=ASC(f$)
2800  IFa<129THEN3020
2820 s$=MID$(in$,j+3,16)
2840 c$=MID$(in$,j+28,1):IFc$<>""THENv=ASC(c$)
2860 q$=MID$(in$,j+29,1):IFq$<>""THENl=ASC(q$)
2880  IFnf=0THEN2940
2900   FORx=1TOnf:IFs$<MID$(d$(x),2,16)THEN2960
2920 NEXTx
2940 x=nf+1:GOTO2980
2960 FORy=nfTOxSTEP-1:d$(y+1)=d$(y):NEXTy
2980 d$(x)=f$+s$+CHR$(v)+CHR$(l):nf=nf+1
3000 PRINTs$;v
3020 IFj>1THEN2760
3040 IFstTHENse=.
3060 IFseTHEN2720
3080 CLOSE5:PRINTnb" {reverse on} block fria {reverse off}":FORi=.TO1300:NEXT:GOSUB1000
3100 GOSUB7100
3120 PRINT"{down*4}{space*4}uppdaterar master directory{.*3}{down}"
3140 IFnx=0THEN3240
3160 FORx=0TOnx-1:c$=LEFT$(x$(x),2):IFdi$<c$THEN3220
3180 IFdi$=c$THEN3280
3200 NEXTx:GOTO3240
3220 FORy=nx-1TOxSTEP-1:x$(y+1)=x$(y):NEXTy:GOTO3260
3240 x=nx
3260 nx=nx+1
3280 x$(x)=di$+dn$:cx=1
3300 GOSUB5960
3320 PRINT#15,"s"+s$:OPEN5,8,5,s$+",s,w":GOSUB8120
3340 PRINT#5,df$;",";nb;cr$;:GOSUB8120
3360 IF nf>0 THEN FOR x=1 TO nf:PRINT#5,d$(x);cr$;
3380 GOSUB8120
3400 NEXTx
3420 CLOSE5:GOSUB6720
3440 cx=0:GOTO540
3460  
3480 REM    display....
3500  
3520 PRINT"{clear}{down*2}{space*6}visa valt directory
3540 GOSUB5700
3560 IFmTHENm=.:GOTO520
3580 PRINT"{reverse on}{blue}{space*2}disknamn, id{space*3}:{black}{reverse off} "dn$", "di$:PRINT:PRINT
3600 GOSUB6120
3620 OPEN5,8,5,s$+",s,r":GOSUB8120
3640 INPUT#5,df$,nb:GOSUB8120
3660 OPEN4,pd:PRINT#4,"{reverse on}{blue}{space*2}disknamn, idkod:{black}{reverse off} "dn$", "di$:
3680 IFst<>.THENGOSUB8220:GOTO520
3700 PRINT#4:PRINT#4,"{reverse on}{blue}{space*6}block fria :{black}{reverse off} "nb
3720 PRINT#4:PRINT#4,"{reverse on}{blue}{space*10}format :{black}{reverse off} "df$:PRINT#4
3740 PRINT#4,"{C*40}":PRINT#4
3760 PRINT"{up*3}":GOSUB9420:PRINT"{down*3}"
3780 nf=0:j=8:IFss<>0THEN4180
3800 GOSUB6500
3820 SYSgin:GOSUB8120
3840 c$=LEFT$(in$,1):ft=ASC(c$)
3860 s$=MID$(in$,2,16)
3880 z=ASC(MID$(in$,18,1))
3900 v=ASC(MID$(in$,19,1))
3920 PRINT#4,RIGHT$("{space*6}"+STR$(z+(256*v)),4)"{space*2}"s$"{space*3}";
3940 IF(ft AND191)=129THENPRINT#4,"seq";:GOTO4020
3960 IF(ft AND191)=130THENPRINT#4,"prg";:GOTO4020
3980 IF(ft AND191)=131THENPRINT#4,"usr";:GOTO4020
3999 IF(ft AND191)=128THENPRINT#4,"del";:GOTO4020
4000 IF(ft AND191)=132THENPRINT#4,"rel";
4020 IF(ft AND64)=64THENPRINT#4,"<";
4021 PRINT#4
4040 IFPEEK(q)>.THENGETc$:IFc$<>""ANDc$<>"q"THENGOSUB1000:GOSUB6420
4060 IFc$="q"THENGOSUB6520:GOTO520
4080 nf=nf+1:IFss=.THEN3820
4100 GOSUB6520
4120 PRINT#4
4140 PRINT#4,nb;" {reverse on}block fria{reverse off}{space*8}";nf;" {reverse on}filer{reverse off}{space*4}"
4160 PRINT#4
4180 IFpd=3THENPRINT"det var "di$", "dn$
4200 GOSUB6260
4220 GOTO520
4240  
4260 REM     delete.....
4280  
4300 PRINT"{clear}{down*2}{space*2}ta bort diskett fr]n master directory"
4320 POKE53280,2:GOSUB5700:POKE53280,15
4340 IFmTHENm=.:GOTO520
4360 PRINT"{down*2}{right*4}tar bort :"di$"{space*2}"dn$:PRINT:PRINT
4380 PRINT#15,"s"+s$
4400 cx=0:FORx=0TOnx-1:IFLEFT$(x$(x),2)=di$THENcx=1
4420 IFcxTHENx$(x)=x$(x+1)
4440 NEXTx:nx=nx-1
4460 INPUT"{space*4}flera ? n{left*3}";c$:IFc$="j"THEN4300
4480 GOSUB6720
4500 GOTO520
4520  
4540 REM      print chart.....
4560  
4580 GOSUB1000:INPUT"{clear}{down*4}{space*7}printer klar?{space*2}j{left*3}";c$:PRINT:IFc$<>"j"THEN540
4600 PRINT"{clear}{down*2}{space*2}printar listan{.*3}":OPEN4,4
4620 PRINT#4,""SPC(15);CHR$(14);"{space*2}disk-idkods lista"
4640 PRINT#4,CHR$(15):PRINT#4," ";
4660 IFst<>.THENGOSUB8220:GOTO520
4680 FORx=48TO90:IFx=58THENx=65
4700 PRINT#4," ";CHR$(x);:NEXTx:PRINT#4
4720 z=0:FORx=48TO90:IFx=58THENx=65
4740 PRINT#4,CHR$(15);" {sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}";
4760 PRINT#4,"{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}{sh asterisk}{sh +}";CHR$(8)
4780 PRINT#4,CHR$(15)CHR$(x);
4800 FORy=48TO90:IFy=58THENy=65
4820 PRINT#4,CHR$(221);:IFz=nxTHEN4880
4840 c$=CHR$(x)+CHR$(y):s$=LEFT$(x$(z),2)
4860 IFs$=c$THENPRINT#4,CHR$(166);:z=z+1:GOTO4900
4880 PRINT#4," ";
4900 NEXTy:PRINT#4,CHR$(221)CHR$(8)
4920 IFPEEK(q)>.THENGOSUB1000:POKEq,.:GOSUB6420
4940 IFc$<>"q"THENNEXTx
4960 PRINT#4,CHR$(15);" {cm z}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}";
4980 PRINT#4,"{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm e}{sh asterisk}{cm x}":GOTO520
5000  
5020 REM     quick list....
5040  
5060 PRINT"{clear}":OPEN4,pd
5080 PRINT#4,"{space*6}{reverse on}{blue}{space*3}disk-idkoder som anv[nds{space*2}{reverse off}{black}"
5100 IFst<>.THENGOSUB8220:GOTO520
5120 PRINT#4:IFnx=.THENz=.:GOTO5220
5140 v=12:IFpd=4THENv=25
5160 z=0:FORx=0TOnx-1:PRINT#4,LEFT$(x$(x),2)" ";
5180 z=z+1:IFz=INT(z/v)*vTHENPRINT#4
5200 NEXTx:PRINT#4:IFz<>INT(z/v)*vTHENPRINT#4
5220 PRINT#4,z;" diskar i master directory":CLOSE4:IFpd=4THEN520
5240 GOSUB6100:IFpd=4GOTO5060
5260 GOTO520
5280  
5300 REM     names & id...
5320  
5340 PRINT"{clear}":PRINT
5360 OPEN4,pd:PRINT#4,"{reverse on}{blue} id{space*2}{.*3} disknamn {.*3}{black}{reverse off}":PRINT#4
5380 IFst<>.THENGOSUB8220:GOTO520
5400 GOSUB9420:PRINT"{down*3}"
5420 c$="":IFnx=.THENGOTO5540
5440 FORx=.TOnx-1
5460 PRINT#4," "LEFT$(x$(x),2)"{space*2}"MID$(x$(x),3)"{space*10}"
5480 IFPEEK(q)>.THENGETc$:IFc$<>""ANDc$<>"q"THENGOSUB1000:GOSUB6420
5500 IFc$="q"THENGOTO520
5520 NEXTx:PRINT#4
5540 PRINT#4,nx;" diskar i master directory{space*9}":CLOSE4
5560 IFpd=4THENGOTO520
5580 GOSUB6100:IFpd=4THENGOTO5360
5600 GOTO520
5620  
5640 REM setup strings for selecion...
5660  
5680 FORx=1TO nr:v$(x)=b$:NEXT:RETURN
5700 v=3:IFnx>0THEN5740
5720 PRINT"{clear}{reverse on}{down*2}{right*4} master directory [r tomt":FORx=1TO150:NEXT:RETURN
5740 sl=1:np=0:v$(0)="{space*2}n[sta sida{.*5}{white}sluta{black}":GOSUB9520
5760 nr=18
5780 sl=sl+np:np=nx-sl+1:IFnp>nrTHENnp=nr
5800 IFnp=.THEN5940
5820 GOSUB5680:PRINT"{home}{down*4}":FORx=.TO18:PRINT"{space*23}":NEXT
5840 FORx=1TOnp:v$(x)=LEFT$(x$(sl+x-2),2)+"{space*4}"+MID$(x$(sl+x-2),3):NEXT
5860 GOSUB8940:IFcl+rl=0THEN5780
5880 di$=LEFT$(x$(sl+v-3),2)
5900 dn$=MID$(x$(sl+v-3),3)
5920 s$="0:dir."+di$:PRINT"{clear}":RETURN
5940 PRINT"{clear}{down*3}{right*4}slut p] filer":FORx=1TO1000:NEXT:m=1:RETURN
5960 s$="0:dir."+di$:RETURN
5980  
6000 f$=LEFT$(f$,16)
6020 IFRIGHT$(f$,1)="*"THENy=LEN(f$)-1:f$=LEFT$(f$,y):RETURN
6040 y=LEN(f$)
6060 f$=LEFT$(f$+"{space*16}",y):RETURN
6080  
6100 GOSUB6480
6120 GOSUB1000:INPUT"{red}{space*4}vill du ha printad kopia? n{left*3}";c$:PRINT"{black}"
6140 pd=3:IFc$="j"THENpd=4:GOSUB6200
6160 IFpd=3THENPRINT"{clear}";
6180 RETURN
6200 GOSUB1000:INPUT"{space*9}printern klar? j{left*3}";c$:PRINT:IFc$<>"j"THEN6120
6220 RETURN
6240  
6260 PRINT"{blue}{space*8}U{D*9}I{space*20}"
6280 PRINT"{reverse on}{space*8}{cm l}{reverse off}{red} return{blue} {cm asterisk}{reverse on} forts[tter{.*3}{space*8}{reverse off}"
6300 PRINT"{up}{space*8}J{F*9}K{space*17}{black}"
6320 IFnTHENRETURN
6340 GOSUB1000
6360 GETc$:IFc$<>CHR$(13)THEN6360
6380 RETURN
6400 :
6420 GETc$:IFc$=""THEN6420
6440 RETURN
6460 :
6480 PRINT"{blue}{reverse on}{space*40}{reverse off}{black}":RETURN
6500 POKE gin+27,192:POKE gin+28,20:RETURN:REM get 20 chars at a time
6520 POKE gin+27,196:POKE gin+28,139:RETURN:REM restore to get full in$
6540 :
6560 INPUT#15,en,em$,et,es:IFen=.THENRETURN
6580 PRINT"{clear}{reverse on}{red} diskfel {black}{reverse off} n[r jag f{pound}rs{pound}kte ";
6600 IFcxTHENPRINT"skriva"
6620 IFcx=0THENPRINT"l[sa"
6640 PRINT:PRINT"referens-filen.":PRINT
6660 PRINTen;em$;et;es
6680 PRINT:PRINT"{reverse on}{red} programmet avslutat! {black}"
6700 GOTO7020
6720 IFcx=0THENRETURN
6740 PRINT"{down*2}{space*4}uppdaterar referensfilen{.*3}":PRINT
6760 IFnx=0THENPRINT#15,"s0:disk dir xref":RETURN
6780 PRINT#15,"s0:dir xref temp"
6800 OPEN5,8,5,"0:dir xref temp,s,w"
6820 GOSUB6560
6840 FORx=0TOnx-1:PRINT#5,CHR$(34)x$(x)cr$;
6860 GOSUB6560
6880 NEXTx
6900 CLOSE5:PRINT#15,"s0:disk dir xref"
6920 PRINT#15,"r0:disk dir xref=0:dir xref temp"
6940 GOSUB6560
6960 RETURN
6980   
7000 PRINT"{black}{clear}"
7020 CLOSE4:CLOSE5:CLOSE15
7040 END
7060  
7080  
7100 PRINT"{clear}"
7120 me$="{space*3}s[tt i programdisken{space*5}"
7140 CLOSE15:GOSUB8280
7160 OPEN15,8,15,"i0":GOSUB8120
7180 PRINT#15,"c0:disk master=0:disk master"
7200 INPUT#15,en,em$
7220 IFen=63THENRETURN
7240 FORx=.TO60:PRINT"{reverse on}{red}fel diskett!{reverse off}{black}":NEXT:GOSUB6480:GOTO7140
7260  
7280 REM    min...
7300  
7320 PRINT"{clear}ange minimum-antal fria block att"
7340 PRINT:PRINT"visas{space*2}0{left*3}";
7360 INPUTs$:REM default=0
7380 y=VAL(s$):IFs$<>"0"ANDy=0THEN520
7400 vf=0:GOTO7560
7420  
7440 REM     max...
7460  
7480 PRINT"{clear}ange maximum-antal fria blocck att"
7500 PRINT:PRINT"visas 99{left*4}";:INPUTs$
7520 y=VAL(s$):IFy=0THEN520
7540 vf=1
7560 OPEN4,pd:PRINT#4:PRINT#4,"{reverse on}{light blue} antal block.id{.*5}namn{.*16}{black}":PRINT
7580 IFst<>.THENGOSUB8220:GOTO520
7600 FORx=0TOnx-1:di$=LEFT$(x$(x),2):dn$=MID$(x$(x),3)
7620 OPEN5,8,5,"0:dir."+di$+",s,r"
7640 GOSUB8120
7660 INPUT#5,df$,nb
7680 GOSUB8120
7700 CLOSE5
7720 IF(vf=0)AND(nb<y)THEN7800
7740 IF(vf=1)AND(nb>y)THEN7800
7760 PRINT#4,RIGHT$("{space*7}"+STR$(nb),7);SPC(6);di$;"{space*5}";dn$
7780 GOSUB9420
7800 IFPEEK(q)>.THENGETc$:IFc$<>""ANDc$<>"q"THENGOSUB6420
7820 IFc$="q"THENCLOSE4:GOTO540
7840 NEXTx:CLOSE4:GOSUB9700
7860 IFpd=3THENGOSUB6100:IFpd=4THEN7560
7880 GOTO540
7900  
7920  
7940 PRINT"{clear}{space*6}{reverse on}**** bam:en [r inkorrekt ****{reverse off}"
7960 GOSUB6480
7980 PRINT:PRINT"den h[r disketten kan ej katalogiseras!":PRINT:PRINT:PRINT
8000 PRINT"var god kontrollera diskettens inneh]ll":PRINT
8020 PRINT"f{pound}re f{pound}rs{pound}k att katalogisera denna disk.":PRINT
8040 GOSUB6480
8060 GOSUB6260:PRINT"{clear}"
8080 GOTO3420
8100  
8120 ss=st:INPUT#15,en,em$,et,es:IFen=.THENRETURN
8140 PRINT"{clear}{reverse on}{red} diskfel! {black}":PRINT
8160 GOTO6660
8180  
8200  
8220 IFst=-128THENPRINTSPC(10)"device not present!
8240 PRINT"{space*2}??":GOSUB6260:RETURN
8260  
8280 PRINT"{clear}"
8300 n=4:IFblTHENco$="{black}":GOTO8340
8320 co$="{white}"
8340 n=n-1
8360 PRINT"{down*4}{light blue}{space*4}U{D*30}I"
8380 PRINT"{light blue}{reverse on}{space*6}{reverse off}"co$;me$"{light blue}{reverse on}{space*6}{reverse off}"
8400 PRINT"{up}{light blue}{space*4}J{F*30}K{black}"
8420 GOSUB6260:GOTO8440
8440 GETc$:IFc$=CHR$(13)THENn=.:GOTO8560
8460 IFc$="q"THEN8560
8480 PRINT"{up*12}"
8500 IFn>1THEN8340
8520 IFblTHENbl=.:GOTO8300
8540 bl=1:GOTO8300
8560 PRINT"{clear}":RETURN
8580  
8600 REM   setup....
8620  
8640 POKE53281,15:POKE53280,15:POKE646,0:GOSUB120
8660 CLR:in$="zz":FORi=.TO5:in$=in$+in$:NEXT
8680 in$=MID$(in$,2):in$=in$+in$
8700 c$="":s$=c$:q$="":z=.:x=.:y=.:l=.:ss=.:q=198:v=.:ad=932:gin=896
8720 IFPEEK(ad)<>162ORPEEK(gin)<>160THENFORi=gin TOad+38:READx:POKEi,x:NEXT
8740 cr$=CHR$(13):DIMd$(230),x$(230),v$(230)
8760 PRINT"{down}{space*8}l[ser referensfilen {.*3}
8780 OPEN15,8,15,"i0"
8800 GOSUB6560
8820 OPEN5,8,5,"0:disk dir xref,s,r"
8840 INPUT#15,en,em$,et,es:IFen=62THEN520
8860 INPUT#5,x$(nx):ss=st
8880 GOSUB6560
8900 nx=nx+1:IFss=0THEN8860
8920 GOTO520
8940  
8960 REM    cursor...
8980  
9000 b$="{space*39}"
9020 xa=214:xb=198:
9040 PRINT"{home}{down*4}":FORx=.TOnp:PRINT"{right}";v$(x)
9060 NEXT
9080 POKExb,0:rl=.:cl=0:GOSUB9300
9100 FORi=0TO1STEP0
9120 GETz$:IFz$=""THEN9120
9140 z=ASC(z$):tc=cl:tr=rl:FORj=0TO1STEP0
9160 IFz=17THENrl=rl+1:IFrl=np+1THENrl=0
9180 IFz=145THENrl=rl-1:IFrl=-1THENrl=np
9200 IFz=13THENi=1
9220 IFv$<>b$THENj=1
9240 NEXT:IF(tc<>cl)OR(tr<>rl)THENGOSUB 9280
9260 NEXT:GOTO9320
9280 POKExa,tr+4:PRINT:PRINT"{right}";v$(tr)
9300 POKExa,rl+4:PRINT:PRINT"{reverse on}{right}";v$(rl):RETURN
9320 v=rl+1
9340 RETURN
9360  
9380 REM   various...
9400  
9420 PRINT"{blue}{space*2}U{D*4}I{space*10}U{D*9}I{space*8}"
9440 PRINT"{reverse on}{space*2}{cm l}{reverse off}{red} q{blue} {cm asterisk}{reverse on}avslutar{space*3}{cm l}{reverse off}{red} annan{blue} {cm asterisk}{reverse on}f{pound}r paus{space*2}{reverse off}"
9460 PRINT"{space*2}J{F*4}K{space*10}J{F*9}K{space*8}{black}{up*3}":RETURN
9480  
9500  
9520 PRINTSPC(30)"{down*5}anv[nd":PRINT
9540 PRINTSPC(28)"UD{red}{reverse on}{sh pound}{cm asterisk}{reverse off}{black}{D*5}I"
9560 PRINTSPC(28)"G {red}cursor{black} H
9580 PRINTSPC(28)"J{F*5}{red}{cm asterisk}{sh pound}{black}FK
9600 PRINT:PRINTSPC(31)"och":PRINT
9620 PRINTSPC(28)"U{D*8}I
9640 PRINTSPC(28)"G {red}return{black} H
9660 PRINTSPC(28)"J{F*8}K
9680 RETURN
9700 FORz=1TO3:PRINT"*{space*37}*":NEXT:RETURN
9720 DATA 160,2,177,45,153,137,0,200,192,6
9740 DATA 208,246,162,5,32,198,255,32,228,255
9760 DATA 164,142,145,140,200,132,142,196,139,208
9780 DATA 242,76,204,255:REM sysgin
9800 DATA 0,0,162,5,32,198
9820 DATA 255,32,207,255,32,207,255,141,162,3
9840 DATA 205,163,3,240,17,176,15,162,18,32
9860 DATA 207,255,202,208,250,164,144,208,3,76
9880 DATA 169,3,76,204,255:REM sysad
9960   
9980 REM visa dir
9999   
10000 PRINT"{clear}{light blue}{reverse on}block{space*5}program/disknamn{space*11}{down}":GOSUB9420:PRINT"{down*3}
10020 OPEN1,8,.,"$":GET#1,a$,a$:e$=CHR$(.):qq=-1
10030 GETa$:IFa$="q"THENCLOSE1:GOSUB6260:GOTO540
10040 IFa$<>""THENPOKE198,.:WAIT198,1:POKE198,.
10050 GET#1,a$,a$,h$,l$:IFstTHENCLOSE1:PRINT"{up}{right*3}{gray} fria":GOSUB6260:GOTO540
10055 IFqqTHENPRINT"{white}",:qq=.:GOTO10065
10060 PRINT"{gray}"RIGHT$(STR$(10000+ASC(h$+e$)+256*ASC(l$+e$)),3)"{black}",
10065 GET#1,a$:IFa$THENIFa$<>CHR$(34)THEN10065
10070 GET#1,a$:IFa$THENIFa$<>CHR$(34)THENPRINTa$;:GOTO10070
10080 GET#1,a$:IFa$THEN10080
10090 PRINT:GOTO10030
stop tok64
(bastext 1.0)