start tok64 d64-nhT3X5
65280 REM{delete}{delete}{delete}{delete}{delete}{delete}{delete}{delete}{delete}OFF
1 POKE808,225:POKE818,116:POKE819,164:POKE774,116:POKE775,164:POKEPEEK(43)+256*PEEK(44)+3,0
4 POKE53280,0:POKE53281,0
5 PRINT"{142}{clear}{space*2}{orange}{reverse on}{space*36}"
6 PRINT"{space*2}{reverse on} a f r i c a n{space*4}a d v e n t u r e "
7 PRINT"{space*2}{reverse on}{space*36}"
8 PRINT"{space*2}{reverse on}{space*4}in search of dr. livingston{space*5}"
9 PRINT"{space*2}{reverse on}{space*36}"
15 PRINT,"{down*3}{light blue}written for the pet
16 PRINTTAB(17)"{down}by
18 PRINT"{orange}{down}{space*5}fullerton, russell & malmberg
30 PRINT,"{down*5}{light blue}adapted for the 64
31 PRINTTAB(16)"{down}by
33 PRINT,"{down}{orange}steven darnold
34 PRINT,"p.o. box 201
35 PRINT,"alexandra, new zealand";
49 DEF FNr(n)=INT(n*RND(1)+.99)
50 x=RND(0):y=1:xg=1:g6$="you don't have it!":g7$="nothing unusual."
51 g8$="with your puny spear ?"
100 g3$="don't be silly!":g2$="you're on your own."
101 g1$="you already have it.":r$=" 'tis done."
102 pm=37:vm=36:nm=60:im=35:DIMv$(vm),n$(nm),i$(im),il(im),ip(im),in(im)
103 DIMp$(pm),p(pm,5),d(22)
104 GOSUB50001
106 IFPEEK(653)<>1THENFORi=1TO2000:NEXT:GOSUB58000
107 GOTO1000
200 GOSUB490:GOTO1000
490 PRINT"{cyan}{down}what next? {gray}";
495 a$="":b$=a$:c$=a$:gv$=a$:gn$=a$:GOSUB60000:a$=in$:PRINT"{156}";
500 z=LEN(a$):IFz=0THEN490
501 IFz-1THEN510
502 IFa$="i"THENv=3:n=0:RETURN
503 v=0:c$=a$:GOTO580
510 GOSUB600:b$=d$:gv$=g$:IFz1=1THENc$=b$:v=0:GOTO580
511 v=0:FORi=1TOvm:IFb$=v$(i)THENv=i:i=vm
512 NEXT:IFv<>0THEN550
520 v=0:c$=b$:GOTO580
550 IF(z-z1)<1THEN590
551 a$=RIGHT$(a$,z-z1):z=LEN(a$):c$=a$
560 IFLEFT$(c$,1)<>" "THEN570
561 c$=RIGHT$(c$,z-1):z=LEN(c$):IFz=0THEN590
562 GOTO560
570 a$=c$:GOSUB600:c$=d$
580 gn$=g$:n=0:FORi=1TOnm:IFc$=n$(i)THENn=i:i=nm
581 NEXT:IFn=60THENn=40
582 RETURN
590 n=0:RETURN
600 i=0:FORii=1TOz:IFMID$(a$,ii,1)=" "THENi=ii:ii=z
601 NEXT:IFi=0THENi=ii
610 d$=LEFT$(a$,i-1):g$=d$:d$=LEFT$(d$,5):z1=LEN(g$):RETURN
1000 PRINT"{clear}{cyan}":j=FRE(0):ga$="{.*5}neither is seen again."
1001 gb$="the native takes your ":gc$="{down}{light blue}you are lying in a soft warm bed"
1002 gd$="you are at the closet.":ge$="{gray}several natives wave hello."
1003 g4$="that's not possible right now.":g5$="it's nowhere in sight."
1004 g9$="{yellow}{down}you had better leave, fast!"
1005 PRINTp$(y):PRINT:d$="{pink}you can see "
1006 z=12:z1=y:IFy<>1ORk<>0THEN1020
1008 IFil(1)=1THENPRINTd$;i$(1):GOTO1080
1009 PRINTd$;g7$:GOTO1080
1010 d$="you have ":z=8:z1=-1
1020 a$=d$:j=1
1030 FORi=1TOim:IFil(i)<>z1ANDil(i)<>-2THEN1070
1035 b$=i$(i):IFi=5ANDil(i)=-2THENIFz1=yORil(2)>2THEN1070
1040 IFj=0THEN1050
1041 j=0:d$=d$+b$:z=LEN(d$):PRINTd$;:GOTO1070
1050 PRINT", ";:IFz+LEN(b$)>37THENPRINT:z=0
1060 d$=b$:z=z+LEN(d$)+2:PRINTd$;
1070 NEXT:IFa$<>d$THENPRINT".":GOTO1077
1071 PRINTd$;:IFz1=yTHENPRINTg7$:GOTO1077
1072 PRINT"nothing."
1077 IFv=3ORv=13THEN1250
1080 IFxb=1THENPRINTgc$
1081 kk=0:FORi=0TO5:IFp(y,i)<>0THENkk=1
1082 NEXT:IFkk=0THEN1090
1083 PRINT"{light blue}{down}obvious directions are:{space*2}";:kk=0
1084 FORi=0TO5:IFp(y,i)=0THEN1088
1085 IFkk<>0THENPRINT" ";
1086 PRINTn$(i+1);:kk=kk+1
1088 NEXT:PRINT:PRINT
1090 IFv=3ORv=13THEN1250
1200 xd=xd+1:IFy=il(8)THEN5000
1201 IFy=17THEN5100
1202 IFy=34THEN5200
1203 IFy=22ORy=27THEN5300
1204 IFy=12THEN5400
1210 IFy1=18ORy=18THEN1250
1211 x7=0
1220 xd=0
1250 zz$="{orange}a native throws a spear at you. it just misses. the native runs off."
1251 IFts=1ORt<30ORy>34ORy<15THEN1260
1255 PRINT:PRINTzz$:il(6)=y:ts=1
1260 IFn4<>0THEN1270
1261 IFil(13)=-1THENn5=n5+1:a$="a charming little flute"
1262 IFn5>16THENPRINT"{down}{orange}after many hours of whittling, the sugar";
1263 IFn5>16THENPRINT"cane is now "a$".":n4=1:il(20)=-1:il(13)=0
1270 IFxe=0ANDy=8THEN1280
1271 GOTO1300
1280 PRINT"{down}{156}oh no . . . your feet are bare . . .{up}":GOTO7000
1300 PRINT:GOSUB490:GOTO1500
1450 IFy=9ORy=10THENPRINT"a fierce black leopard bars the way.":GOTO1200
1452 IFy<>15THEN1460
1454 IFil(17)=-1THENil(17)=35:PRINT"livingstone is captured by natives.":GOTO1200
1456 z=8:GOTO1540
1460 IFy<>32THEN1470
1461 IFFNr(5)<3THENy=34:GOTO1000
1462 y=31:GOTO1000
1470 PRINT"that leads to quicksand.":GOTO1200
1500 t=t+1:IFvTHEN1600
1501 IFnTHEN1520
1510 i=FNr(3):IFi=1THENPRINT"what?"
1511 IFi=2THENPRINT"huh?"
1512 IFi=3THENPRINT"what in the world are you talking about?"
1515 GOTO1200
1520 IFn>12THEN1550
1521 IFn<7THEN1525
1522 n=n-6
1525 z=p(y,n-1)
1530 IFz<0THEN1560
1531 IFz=98THEN1450
1532 IFz<>0THEN1540
1533 i=FNr(3):IFi=1THENPRINT"that direction is sealed off."
1534 IFi=2THENPRINT"you won't get anywhere going there."
1535 IFi=3THENPRINT"you can't go that way."
1536 GOTO1200
1540 y1=y:y=z:GOTO1000
1550 PRINT"what do you want to do with{space*13}the ";gn$;"?":GOTO1200
1560 IFRND(1)<.5THENz=0:GOTO1530
1561 y=-z:GOTO1585
1570 IFy=12THENIFRND(1)<.25THENy=11
1571 GOTO1000
1580 IFy=22THENIFRND(1)<.5THENy=21:GOTO1000
1581 y=19:GOTO1000
1585 IFy=26AND(RND(1)>.8)THENi$(14)="a hungry alligator"
1586 GOTO1000
1600 ONvGOTO1614,1800,1010,1900,1900,2100,2200,1000,2900,2500
1601 zz=v-10
1602 ONzzGOTO2600,2700,1010,2400,3000,3100,3200,3300,3400,3500
1603 zz=v-20
1604 ONzzGOTO2700,3600,3760,3800,3900,3700,3400,4000,4000,4100
1611 zz=v-30
1612 ONzzGOTO1614,3600,4500,4500,4600,4700
1614 IFn=0THENPRINT"who knows what a "gn$" is?":GOTO1300
1615 IFmi>4THENPRINT"your load's too heavy.":GOTO1300
1617 IFn=16ANDv5=1ANDil(18)=yTHENi=18:GOTO1690
1620 IFv5ANDn=16THEN1630
1621 GOSUB5900:IFx1>0THEN3710
1625 IFn=11THENn=22:GOTO2740
1627 IFn<>34THEN1630
1628 IFy=33THEN3720
1629 GOTO5960
1630 IFn=24THEN1700
1631 ii=0:FORi=1TOim:IFn=in(i)THENii=i:i=im
1632 NEXTi:IFii=0THEN1510
1633 i=ii
1635 IFNOT(il(i)=-1OR(il(2)=-1ANDil(i)=-2))THEN1640
1636 IFi=7THENPRINTLEFT$(g1$,17)+"him.":GOTO1200
1637 PRINTg1$:GOTO1200
1640 IFil(i)<>yOR(y=1ANDk=0ANDi<>1)THEN5960
1642 IFxbTHENIFi<>1THENPRINT"from bed?":GOTO1220
1645 IFn=18THEN3600
1646 IFi=2ANDil(5)=-2THENmi=mi+1
1650 IFn<>37THEN1660
1651 IFxf=1THEN1690
1652 PRINT"it's not free.":GOTO1200
1660 IFn<>38THEN1665
1661 IFi$(14)="a hungry alligator"THENPRINT"the alligator is in the way!":GOTO1200
1664 PRINT"dr.livingston?{down}";:GOSUB60000:IFin$<>"i presume"THENGOSUB500:GOTO1500
1665 IFn<>48THEN1670
1666 IFil(29)<>-1THEN7000
1667 IFy=4THENPRINT"a deadly spider jumps out of the wood{space*3}and crawls away.{down}{yellow}"
1670 IFn=49THENPRINT"it's too hot.":GOTO1200
1671 IFn<>47THEN1690
1672 IFil(23)=yTHENi=23:GOTO1690
1673 IFil(26)<>-1THENPRINT"you need a cage.":GOTO1200
1674 il(26)=0:il(22)=0:il(23)=y:in(22)=0:mi=mi-1:GOTO1000
1690 PRINTr$
1695 il(i)=-1:mi=mi+1:GOTO1200
1700 IFxeTHENPRINT"you're wearing them.":GOTO1200
1710 IFk<>1THEN1720
1711 PRINT"your feet are now snug in a pair of{space*5}hiking boots.":xe=1
1712 il(7)=0:GOTO1300
1720 PRINT"what boots?":GOTO1300
1800 IFn=0THEN1510
1810 IFn=24THENPRINT"they're stuck.":GOTO1200
1811 ii=0:FORi=1TOim:IFin(i)=nTHENii=i:i=im
1812 NEXTi:IFii=0THEN1510
1813 i=ii
1820 IFil(i)>-1THEN3100
1821 IFy=1ANDk=0ANDi>1THENPRINT"there's no room.":GOTO1300
1830 IFil(i)<>-2THEN1840
1831 IFil(2)=-1THEN3100
1832 GOTO5950
1840 IFn=16THEN3110
1841 IFi=2ANDil(5)=-2THENmi=mi-1
1890 il(i)=y:PRINTr$:GOSUB3480
1895 mi=mi-1:GOTO1200
1900 b$="it's already ":c$=b$+"closed.":a$=b$+"open.":d$="from bed?"
1901 IFn=0THEN1510
1902 IFv=5THEN2000
1905 IFy-1THEN1930
1906 IFn-22THEN1920
1910 IFxb=1THENPRINTd$:GOTO1200
1915 IFk=0THENk=1:GOTO1000
1916 PRINTa$:GOTO1200
1920 IFn<>20THEN1930
1921 IFil(1)<>-1THEN5950
1922 IFxc=0THENPRINT"the book falls open to an underlined{space*4}passage.":xc=1:GOTO1200
1923 PRINTa$:GOTO1200
1930 IFn<>13THEN1940
1931 IFil(2)<>-1THEN5950
1932 IFil(2)=-1THENPRINTa$
1933 IFxx<>2THENPRINT"something fell out."
1934 IFxx=1THENxx=2:il(31)=y
1935 IFxx=0THENxx=1:il(28)=y
1936 GOTO1200
1940 IFn<>55THEN1960
1942 IFil(34)<>0THENPRINT"it's already open.":GOTO1200
1944 IFil(32)<>0THENPRINT"it's locked.":GOTO1200
1946 IFil(33)=-1THENPRINT"put it down first.":GOTO1200
1948 IFil(33)<>yTHENPRINT"it's not here.":GOTO1200
1950 PRINT"ok, it's open.":il(34)=y:in(34)=55:il(33)=0:in(33)=0:il(35)=y
1952 GOTO1200
1960 IFn<>50THEN1510
1962 IFil(23)=yORil(23)=-1THEN3131
1965 IFil(26)=yORil(26)=-1THENPRINT"ok, it's open.":GOTO1200
1966 PRINT"it's not here.":GOTO1200
2000 IFy-1THEN2020
2001 IFn-22THEN2010
2005 IFxb=1THENPRINTd$:GOTO1200
2007 IFk=1THENk=0:GOTO1000
2008 PRINTc$:GOTO1200
2010 IFn<>20THEN2020
2011 IFil(1)<>-1THEN5950
2012 IFxc=1THENPRINTr$:xc=0:GOTO1200
2013 PRINTc$:GOTO1200
2020 IFn<>13THEN2030
2021 IFil(2)<>-1THEN5950
2022 IFil(5)=-2THENPRINT"the mouse won't escape!":GOTO1200
2023 PRINT"it'll just fall open again.":GOTO1200
2030 IFn<>55THEN2050
2031 tt$="ok, it's closed."
2032 IFil(32)<>0ORil(33)<>0THENPRINT"it's already closed.":GOTO1200
2034 IFil(34)=-1THENPRINT"put it down first.":GOTO1200
2036 IFil(34)<>yTHENPRINT"it's not here.":GOt1200
2040 IFil(34)=yTHENPRINTtt$:il(33)=y:in(33)=55:il(34)=0:in(34)=0
2045 GOTO1200
2050 IFn<>50THEN1510
2055 IFil(26)=yORil(26)=-1THENPRINT"ok, it's closed.":GOTO1200
2056 PRINT"it's not here.":GOTO1200
2100 IFy=2THEN2210
2101 IFil(1)=-1AND xb=1THENil(1)=1:mi=mi-1:y=2:xb=0:GOTO1000
2102 GOTO1510
2200 IFn>0THEN1510
2201 IFy<>1THEN2205
2202 y=12:xb=0:IFil(1)=-1THENmi=mi-1:il(1)=1
2203 GOTO1000
2205 IFy<>12THEN1510
2206 IFil(17)=-1THENil(17)=35:PRINT,,"{light blue}{>*3} {pink}help! {light blue}{<*3}":mi=mi-1:FORj=1TO5e3:NEXT
2210 y=1:GOTO1000
2400 IFy<>29THEN2410
2401 IFn<>40THEN2420
2402 IFil(4)<>-1THEN5950
2403 PRINTgb$"groundnuts.":xf=1:il(4)=0:mi=mi-1:GOTO1200
2410 IFy<>17THEN2420
2411 IFn<>42THEN2420
2412 IFil(10)<>-1THEN5950
2413 PRINTgb$"beans, gives you a trinket, then runs away.";:
2414 xg=0:n$(26)="ring":il(10)=0:il(19)=-1:GOTO1200
2420 PRINT"no way, jose!":GOTO1200
2500 IFy=1THENPRINT"this may seem absurd but in the book is a magical word":GOTO1250
2505 IFy=4THENPRINT"latin-speaking spiders say 'olfacere'":GOTO1250
2507 IFy=10THENPRINT"squeek!":GOTO1250
2510 IFy=23ORy=24THENPRINT"you won't make it with a 'hop' or 'skip'":GOTO1250
2520 IFy=25ORy=22ORy=27THENPRINT"be persistent.":GOTO1250
2530 IF(y=34ORy=17)ANDil(6)=-1THENPRINT"you look hostile.":GOTO1250
2535 IFy=37THENPRINT"explore.":GOTO1250
2540 IFy=34THENPRINT"lion traps circle the village.":GOTO1250
2545 IFy=36THENPRINT"there's a big row of roms over there.":GOTO1250
2560 PRINTg2$:GOTO1250
2600 a$="africa - land of the unknown{space*18}by r.u. redde"
2601 b$="{.*3}plorer nodded off to sleep, his{space*6}thoughts began to drift{.*3}"
2602 b$=b$+"drift{.*3}drift"
2605 IFn<>36THEN2610
2606 IFil(11)=-1THENPRINT"it says: {yellow}vip flip dog bog":GOTO1200
2607 GOTO5950
2610 IFn<>19THEN2620
2611 IFy=29ORy=33THENPRINT"trading post":GOTO1200
2612 IFy<>31THEN5950
2613 PRINT"ujiji country {-*3} keep out!!"
2614 PRINT"no heed 'em {-*3} we eat 'em":GOTO1200
2620 IFNOT(n=20ORn=25)THEN1510
2621 IFil(1)<>-1THEN5950
2622 IFxb<>1THENPRINT"try reading in bed.":GOTO1200
2623 IFn<>20THEN2630
2624 PRINTa$:GOTO1200
2630 IFxc=1THENPRINTb$:GOTO1200
2631 GOTO5960
2700 IFn=0THEN1510
2701 IFn<13THEN1520
2702 IFn=17THEN3800
2703 IFn=21ANDy=3THENy=2:GOTO1000
2704 IFn=46ANDy=17THENy=18:GOTO1000
2705 IFn=56ORn=57ORn=59THEN4500
2740 IFn=22ANDy=1THENPRINTgd$:xb=0:GOTO1200
2741 IFn<>23THEN2760
2742 IFy=1THENPRINTgc$:xb=1:GOTO1300
2743 PRINT"in darkest africa?":GOTO1200
2760 IFn=41ANDy=34THENy=35:GOTO1000
2761 IFn<>29THEN2770
2762 IFy<>16THEN2765
2763 y=17:GOTO1000
2765 IFy=32THENn=3:GOTO1525
2770 GOTO1510
2900 IFn<>35THEN2910
2901 IFil(16)=-1THEN2920
2902 GOTO5950
2910 IFn<>14THENPRINTg3$:GOTO1200
2911 IFil(6)<>-1THEN5950
2920 PRINT"it sails through the air{.*7}and hits the ";
2921 IFy=2THENPRINT"water, quickly sinking.":j=0:GOTO2940
2930 j=y:IFy=1THENPRINT"floor":GOTO2935
2931 PRINT"ground"
2935 IFy=7THENj=6
2940 IFn=14THENil(6)=j
2941 IFn<>14THENil(16)=j
2945 IFil(14)<>il(16)THEN2950
2946 FORi=1TO2000:NEXT
2947 PRINT"{down}{white}wait!{space*2}that's not ground.{156}"
2948 FORi=1TO2000:NEXT
2949 PRINT"{down}it's alligator!":i$(14)="a dead alligator"
2950 GOTO1895
3000 IF(y=17ORy=34ORy=29)ANDn=44ANDil(6)=-1THENPRINTg8$:GOTO1200
3001 GOTO3710
3100 IFn<>18THEN3110
3101 IFNOT(il(5)=-2ANDil(2)=-1)THEN5950
3102 IFy=9ORy=10THEN3105
3103 PRINT"the mouse jumps out and scampers off.":il(5)=2:GOTO1895
3105 PRINT"the mouse jumps out and startles the{space*4}leopard into flight.";ga$
3106 p(9,4)=10:p(10,5)=9:il(5)=0:GOTO1895
3110 IFn<>16THEN3130
3111 IFil(18)<>-1THEN5950
3112 IFy=22THEN3116
3113 PRINT"the viper slowly slithers away.":il(18)=7:GOTO1895
3116 PRINT"the viper wakes up and attacks the dog{space*2}and both fall into the";
3117 PRINT" quicksand.":PRINTga$:il(15)=0:il(18)=0
3120 il(21)=y:PRINT
3121 PRINT"something sparkles in the grass.":GOTO1895
3130 IFn<>47THEN5950
3131 PRINT"the lion is free.":il(23)=0:il(22)=y:il(26)=-1:in(22)=47:GOTO1200
3200 IFn<>16THEN3710
3201 IFv5<>0THENPRINT"again?":GOTO1200
3202 IFy<>il(8)THENPRINTg5$:GOTO1200
3203 IFil(20)<>-1THENPRINT"you may have good looks,but{.*4}":GOTO1200
3204 v5=1:PRINTr$:il(18)=y:il(8)=0:GOTO1210
3300 IFn=43THEN3310
3301 PRINT"jump what?":GOTO1200
3310 IFy<23ORy>24THENPRINT"there isn't any quicksand here.":GOTO1200
3320 PRINT"do you really expect to jump over 30 ft?"
3321 GETa$:IFa$=""THEN3321
3322 IFa$<>"y"THENGOSUB500:GOTO1500
3330 PRINT"ok - here goes{.*4}j u m p {!*3}":FORi=1TO1000:NEXT
3360 PRINT"ta da{!*3}":FORi=1TO1000:NEXT:IFy=23THENy=24:GOTO1000
3361 y=23:GOTO1000
3400 GOSUB3480
3410 PRINT"{down*2}{cyan}your score is"ss"points out of 300."
3411 PRINT"{down}{space*3}you've taken"t"turns.{down}":IFv<>27THEN1250
3420 IFd$="quit"THENEND
3425 GOSUB4300:IFreOR(t<150)THENPRINT"are dead.{reverse off}{up}{left*9}{cm @*9}{down*2}":END
3430 PRINT"{reverse on}have recovered.{reverse off}{up}{left*15}{cm @*15}{down}":mi=0
3431 FORi=2TOim:IFil(i)=-1THENil(i)=FNr(25)+10
3432 NEXT
3435 FORi=1TO5000:NEXT:GOSUB61000
3440 y=2:re=1:GOTO1000
3480 ss=0:FORi=1TOim:IFil(i)=1THENss=ss+ip(i)
3485 NEXTi:IFss<300THENRETURN
3490 GOSUB4300:PRINT"{reverse on}win.{reverse off}{up}{left*4}{cm @*4}{down}":GOTO3490
3500 IFn=0THEN1510
3501 IFy=1ORy>3THEN3530
3505 IFn=21THENPRINT"where?":GOTO1200
3520 IFy=2OR(y=3AND(n=10ORn=4))THEN2700
3530 IFy=23ORy=24THENPRINT"on quicksand?":GOTO1200
3540 PRINT"on land?":GOTO1200
3600 IFn=47THEN1670
3601 IFn<>18THEN3710
3602 IFy<>il(5)THEN5960
3603 IFil(2)=-1THEN3606
3604 PRINT"you don't have anything to put it in.":GOTO1200
3606 PRINT"the mouse is now lost in the folds of{space*3}your knapsack."
3607 i=0:il(5)=-2:GOTO1695
3700 IFn=18ORn=34THENPRINT"it just ate.":GOTO1200
3710 IFn=0THEN1510
3711 GOSUB5900:IFx1=1THENPRINTg4$:GOTO1200
3712 IFx1=2THEN5960
3720 IFNOT(n=18ORn=34)THEN3730
3721 IFv=17THENPRINT"rodents are charming enough!":GOTO1200
3722 PRINT"it's too quick.":GOTO1200
3730 PRINTg3$:GOTO1200
3760 IFy<>18THEN1510
3761 y=17:GOTO1000
3800 IFy=6ORy=7THENy=7:GOTO1000
3801 GOTO1510
3900 a$="{.*4}u{m*5} g{o*4}d!"
3901 IFn=18ANDil(5)=-2ANDil(2)=-1THENPRINT"y u k{!*3}":il(5)=0:GOTO1895
3920 ii=0:FORi=1TOim:IFin(i)=nTHENii=i:i=im
3921 NEXTi:IFii=0THEN3960
3922 IFil(ii)<>-1THEN5950
3923 IFn=42ORn=53ORn=40ORn=39THENPRINTr$;a$:il(ii)=0:GOTO1895
3945 IFn=0THEN1510
3950 GOSUB5900:IFx1=1THENPRINTg4$:GOTO1200
3960 PRINTg3$:GOTO1200
4000 IFn<>49THEN4010
4001 IFil(28)<>-1THENPRINT"you have no matches.":GOTO1200
4002 IFil(24)=-1THENPRINT"prepare the wood.":GOTO1200
4003 IFil(24)<>yTHENPRINT"you need wood.":GOTO1200
4004 PRINT"the fire is blazing.":il(24)=0:il(25)=y:GOTO1200
4010 IFn<>50THEN1510
4011 IFil(27)<>-1THENPRINT"you have no tools.":GOTO1200
4012 IFil(24)<>-1THENPRINT"you have no wood.":GOTO1200
4013 il(26)=y:il(24)=0:GOTO1000
4100 IFn=49ORn=48THEN4001
4101 IFn<>52THEN4104
4102 PRINT"the matches are blazing brightly.":il(28)=0:il(30)=-1:in(28)=0
4103 GOTO1200
4104 IFn=50ANDil(28)=-1THENil(26)=0:GOTO4004
4105 PRINT"be careful with fire, stupid!":GOTO1200
4300 FORi=1TO1500:NEXT:FORi=1TO50:PRINTCHR$(14);:FORj=1TO40:NEXT
4305 PRINTCHR$(142);:FORj=1TO40:NEXT:NEXT
4310 FORs=1TO400:NEXT:FORi=1TO15:PRINT"{pink}{cm s}{left}{down}{cm z}";:FORs=1TO99:NEXT:NEXT
4320 PRINT"{reverse on} you {reverse off}{up}{left*5}{cm @*5}{down}{reverse on}";:RETURN
4500 IFy=36ORy=37THEN4502
4501 GOTO1510
4502 IFn=56ORn=57THENy=37:GOTO1000
4503 IFn=59ANDil(32)=0THENil(32)=37:PRINT"look!{space*2}a chest!":GOTO1200
4504 GOTO1510
4600 IFn<>55THEN1510
4601 tt$="ok, it's unlocked."
4610 IFil(33)<>0ORil(34)<>0THENPRINT"it's already unlocked.":GOTO1200
4615 IFil(31)<>-1THENPRINT"you don't have the key.":GOTO1200
4620 IFil(32)=-1THENPRINT"put it down first.":GOTO1200
4630 IFil(32)<>yTHENPRINT"it's not here.":GOTO1200
4640 IFil(32)=yTHENPRINTtt$:il(32)=0:in(32)=0:il(33)=y:in(33)=55
4650 GOTO1200
4700 IFn<>55THEN1510
4701 tt$="ok, it's locked."
4710 IFil(32)<>0THENPRINT"it's already locked.":GOTO1200
4715 IFil(31)<>-1THENPRINT"you don't have the key.":GOTO1200
4720 IFil(33)=-1ORil(34)=-1THENPRINT"put it down first.":GOTO1200
4730 IFil(33)=yTHENPRINTtt$:il(33)=0:in(33)=0:il(32)=y:in(32)=55
4740 IFil(34)=yTHENPRINTtt$:il(34)=0:in(34)=0:il(32)=y:in(32)=55
4750 GOTO1200
5000 IFv5<>0THEN1210
5001 IFxd=2THEN5140
5002 IFxd>2THEN7000
5003 GOTO1250
5100 IFx7THEN5110
5101 x7=1:IFil(6)=-1THEN5130
5102 GOTO5120
5110 IFil(6)<>-1THEN5150
5111 IFxd>3THEN7000
5112 GOTO5140
5120 IFxg=0THEN1210
5121 PRINT"{yellow}a friendly native approaches with some"
5122 PRINT"trinkets.{space*2}it appears he wants make a{space*3}trade.":GOTO1220
5130 PRINT"suddenly a volley of spears flies over"
5131 PRINT"your head.{space*2}an obvious warning!"
5140 PRINTg9$:GOTO1250
5150 PRINT:PRINTge$:GOTO1220
5200 IFx7THEN5110
5201 x7=1:IFil(6)=-1THEN5130
5202 GOTO5150
5300 IFy=il(15)ANDi$(15)="a wild dog"THEN5303
5301 IFy=il(14)ANDi$(14)="a hungry alligator"THEN5303
5302 GOTO1210
5303 IFxd>5THEN7000
5304 IFxd>1THENPRINTg9$
5310 GOTO1250
5400 IFRND(1)>.9THENPRINT"{156}a voice echoes high above you . . .{space*5}p l u g h !"
5401 IFt>200ANDss<40THEN7000
5402 GOTO1210
5900 x1=0:IFn=16ORn=27ORn=32ORn=33ORn=47THEN5907
5901 RETURN
5907 tt$="badly wounded, it crawls away.":IFn=47ANDil(23)THENRETURN
5908 x1=1:IFil(6)=-1ORil(16)=-1THEN5910
5909 RETURN
5910 qq=0
5912 IFn=16ANDv=15ANDil(8)=yTHENx1=2
5913 IFn=47ANDv=15ANDil(22)=yTHENx1=2
5914 IFx1=2THENPRINTtt$:qq=1:xd=0
5915 IFqq=0THENx1=1:RETURN
5916 ii=0:FORi=1TOim:IFin(i)=nTHENii=i:i=im
5917 NEXT:IFy>3THENil(ii)=y-1
5920 RETURN
5950 IFn=38THENPRINTLEFT$(g6$,15)+"him.":GOTO1200
5951 PRINTg6$:GOTO1200
5960 IFn=38THENPRINT"he"+RIGHT$(g5$,20):GOTO1200
5970 PRINTg5$:GOTO1200
7000 PRINT"{down}"
7001 IFy=8THENPRINT"a scorpion bites you on the toe.":GOTO7011
7002 IFy=7THENPRINT"the viper sinks its fangs into you.":GOTO7011
7003 IFy=27THENPRINT"the alligator bites off your leg.":GOTO7011
7004 IFy=4THENPRINT"a deadly spider hidden in the wood bitesyour hand.":GOTO7011
7005 IFy=34THENPRINT"the ujiji capture you and start cooking you.":GOTO7011
7007 IFy=22THENPRINT"the wild dog tears out your throat.":GOTO7011
7009 IFy=17THENPRINT"a poison-tipped spear hits you in the{space*3}back.":GOTO7011
7010 PRINT:PRINT"you are stricken by a horrible fever."
7011 v=27:GOTO3400
50001 p$(1)="you are in a bedroom, wearing pyjamas.{space*2}"
50002 p$(1)=p$(1)+"a nightstand is between the closet and{space*2}the bed."
50003 p$(1)=p$(1)+"{space*2}the bedcovers are turned down."
50004 p$(2)="you are drifting in a row boat on a big lake."
50005 p$(2)=p$(2)+" there is a beach on the eastern{space*3}shoreline."
50020 p$(3)="you are on the eastern shoreline.{space*2}a{space*4}boat is tied to the dock."
50021 p$(4)="you are on a grassy plain."
50022 p$(5)=""
50023 p$(6)="a trail begins here.{space*2}off to one side{space*3}is a tree."
50060 p$(7)="you are precariously balanced in a{space*6}moss-covered tree."
50061 p$(8)="you are on a north-south trail.{space*2}cliffs to the east "
50062 p$(8)=p$(8)+"reach up to a plateau."
50063 p$(9)="you are at the foot of a cliff.{space*2}a path leads up to an opening."
50110 p$(10)="you are at the mouth of a cave. a trail leads downward."
50111 p$(11)="you are in a tunnel.{space*2}a faint glow is tothe west of you."
50112 p$(11)=p$(11)+" a sign on the wall says{orange}{space*2}caverns ahead"
50113 p$(11)=p$(11)+"--enter at your own risk"
50130 p$(12)="you are in an immense cavern.{space*2}the wallsare covered with"
50131 p$(12)=p$(12)+" an iridescent glow."
50132 p$(13)="you are in a long east-west tunnel.{space*5}"
50133 p$(13)=p$(13)+"there is a hole in the north wall."
50134 p$(15)="the trail here is overgrown with grass."
50135 p$(16)="the trail widens out to a nearby{space*8}village."
50140 p$(17)="you are in a native village.{space*2}there are several campfires about."
50141 p$(18)="you are in a grass hut."
50142 p$(19)="you are at the edge of the jungle.{space*6}a trail leads north."
50143 p$(20)="you are at the edge of the jungle. grasslands extend to"
50144 p$(20)=p$(20)+" the east and south."
50145 p$(17)=p$(17)+" the witch{space*6}doctor's hut is to the south."
50160 p$(21)="you are in a jungle.{space*2}trails lead off inseveral directions."
50161 p$(22)=""
50162 p$(23)="there is a large body of quicksand here with a trail just beyond.
50163 p$(24)=""
50164 p$(25)=""
50165 p$(26)="you are on a grassy plains. the terrain is becoming marshy."
50170 p$(27)="you are in the marshes.{space*2}something is{space*3}moving in the grass."
50171 p$(28)="you are in a valley. a small opening{space*4}marks the hill beside"
50172 p$(28)=p$(28)+" you. rolling hillsflow southward."
50180 p$(29)="you are at a trading post.{space*2}an eager{space*4}native smiles at you as"
50181 p$(29)=p$(29)+" he points to hissign."
50182 p$(30)="you are in a field of corn.{space*2}the ground drops off to the north."
50183 p$(31)="you are on a grassy plains. two shrunkenheads decorate a sign."
50190 p$(32)="you are on the plains.{space*2}a village lies{space*2}to the east."
50191 p$(33)="you are behind a hut.{space*2}there is a sign{space*2}in the ground. a"
50192 p$(33)=p$(33)+" squirrel just ran by."
50200 p$(34)="you are in a ujiji village.{space*2}a native{space*3}stands near holding a"
50201 p$(34)=p$(34)+" spear.{space*2}he looks{space*2}excitied."
50202 p$(35)="you are in a pit.{space*2}light streams in fromabove."
50210 p$(36)="you are lost inside the computer, some- where under the keyboard."
50211 p$(36)=p$(36)+"{space*2}strange and{space*3}wonderous components are all around."
50220 p$(37)="you are inside an obsolete set of roms. undocumented pointers"
50221 p$(37)=p$(37)+" are all around."
50900 p$(5)=p$(4):p$(14)=p$(10):p$(22)=p$(21):p$(25)=p$(21):p$(24)=p$(23)
50901 FORi=1TOpm:FORj=0TO5:READ p(i,j):NEXTj,i
52001 DATA0,0,0,0,0,0
52002 DATA0,0,3,0,0,0
52003 DATA0,5,4,2,0,0
52004 DATA5,6,4,3,0,0
52005 DATA3,0,6,4,0,0
52006 DATA5,8,4,5,7,0
52007 DATA0,0,0,0,7,6
52008 DATA6,15,9,0,0,0
52009 DATA0,0,0,8,98,0
52010 DATA0,0,11,0,0,98
52011 DATA0,0,12,10,0,13
52012 DATA11,14,14,13,36,14
52013 DATA11,0,14,10,0
52014 DATA0,0,0,0,13,0
52015 DATA28,0,0,16,98,0
52016 DATA0,15,19,17,19,0
52017 DATA0,16,18,0,0,0
52018 DATA0,17,0,0,0,0
52019 DATA0,16,22,20,21,0
52020 DATA0,0,26,26,19,0
52021 DATA0,21,23,22,21,21
52022 DATA21,21,22,19,23,22
52023 DATA22,98,22,98,21,23
52024 DATA23,24,98,25,98,24
52025 DATA24,-20,25,-20,24,25
52026 DATA25,20,27,30,20,0
52027 DATA0,27,27,-26,27,27
52028 DATA27,0,30,29,0,14
52029 DATA0,0,0,0,28,0
52030 DATA0,28,26,0,31,0
52031 DATA0,30,32,33,31,0
52032 DATA0,31,0,98,31,0
52033 DATA0,0,0,0,31,0
52034 DATA0,34,34,34,32,0
52035 DATA35,0,0,36,13,34,0
52036 DATA0,12,0,35,0,12
52037 DATA0,0,36,0,0,0
53000 FORi=1TOvm:READv$(i):NEXT
53001 DATAget,drop,i,open,close,drift,plugh,look,throw,help
53002 DATAread,go,inven,trade,kill,free,charm,jump,score,row
53003 DATAenter,catch,exit,climb,eat,feed,quit,build,make,light
53004 DATAtake,captu,check,exami,unloc,lock
54000 FORi=1TOnm:READn$(i):NEXT
54001 DATAn,s,e,w,u,d,north,south,east,west
54002 DATAup,down,knaps,spear,flute,viper,tree,mouse,sign,book
54003 DATAboat,close,bed,boots,passa,"",leopa,diamo,villa,trink
54004 DATAcane,dog,allig,squir,dagge,note,chain,livin,corn,groun
54005 DATApit,beans,quick,nativ,sapph,hut,lion,wood,fire,cage
54006 DATAtoolk,match,stuff,keys,chest,rom,roms,gold,point,nuts
55000 FORi=1TOim:READi$(i):NEXT
55001 DATAa timeworn book,a faded red knapsack,ears of corn
55002 DATAa batch of groundnuts,a tiny grey mouse,a poison-tipped spear
55003 DATAa pair of hiking boots,a vicious viper,a sparkling diamond
55004 DATAa sack of coffee beans,a crumpled note,a solid silver chain
55005 DATAseveral stalks of sugar cane,a hungry alligator,a wild dog
55006 DATAa pearl-handled dagger,dr. livingston,a lethargic viper
55007 DATAa golden nose ring,a charming little flute,a deep-blue sapphire
55008 DATAa rare albino lion,a caged albino lion,a pile of wood
55009 DATAa blazing fire,a strong wooden cage,a toolkit cartridge
55010 DATAa book of matches,some foul-smelling stuff,a book of burnt matches
55011 DATAa ring of rusty keys,a locked chest,an unlocked chest
55012 DATAan empty chest,king soloman's gold
56000 FORi=1TOim:READil(i),ip(i),in(i):NEXT
56001 DATA1,0,20
56002 DATA1,0,13
56003 DATA30,0,39
56004 DATA33,0,40
56005 DATA2,0,18
56006 DATA0,0,14
56007 DATA1,0,24
56008 DATA7,0,16
56009 DATA25,10,28
56010 DATA15,0,42
56011 DATA18,0,36
56012 DATA29,20,37
56013 DATA24,0,31
56014 DATA27,0,33
56015 DATA22,0,32
56016 DATA18,10,35
56017 DATA27,100,38
56018 DATA0,0,16
56019 DATA0,20,26
56020 DATA0,0,15
56021 DATA0,50,45
56022 DATA26,0,47
56023 DATA0,70,47
56024 DATA4,0,48
56025 DATA0,0,49
56026 DATA0,0,50
56027 DATA36,0,51
56028 DATA0,0,52
56029 DATA18,0,53
56030 DATA0,0,52
56031 DATA0,0,54
56032 DATA0,0,55
56033 DATA0,0,0
56034 DATA0,0,0
56035 DATA0,20,58
56100 RETURN
58000 PRINT"{clear}{white} a f r i c a n{space*5}a d v e n t u r e"
58010 PRINT"{pink}{down}dr. livingston is again lost in the"
58020 PRINT"darkest out-reaches of africa.{space*2}his"
58030 PRINT"rescue is your main objective.
58040 PRINT"{light blue}{down}to explore the terrain and rescue"
58050 PRINT"dr. livingston, enter two-word commands
58060 PRINT"like {cyan}go east{light blue}, {cyan}catch lion{light blue} or {cyan}get book{light blue}.
58070 PRINT"movements may be entered by typing in
58080 PRINT"just the first letter of the direction
58090 PRINT"in which you wish to move."
58100 PRINT"{pink}{down}the computer's vocabulary is limited,"
58110 PRINT"so if a word doesn't seem to work, try"
58120 PRINT"a new word or another approach."
58130 PRINT"{light blue}{down}in addition to livingston, you will"
58140 PRINT"earn points for each valuable you return";
58150 PRINT"to your bedroom.{space*2}note, however, that
58160 PRINT"some valuables may be useful in other"
58170 PRINT"ways.{space*2}so, be creative.{down}{white}
58180 GOSUB61000
58190 PRINT"{clear}{light blue}there are several helpful commands to"
58200 PRINT"use during your adventure:"
58210 PRINT"{down}{cyan}help{pink}--sometimes will give you a hint"
58220 PRINT"{down}{cyan}look{pink}--describes your surroundings"
58230 PRINT"{down}{cyan}i{light blue} or {cyan}inventory{pink}--lists the items in"
58240 PRINT"{space*16}your possession"
58250 PRINT"{down}{cyan}score{pink}--shows total points earned"
58260 PRINT"{down}{cyan}quit{pink}--ends game and gives final score"
58270 PRINT"{light blue}{down*2}in your adventure you will encounter
58280 PRINT"danger and excitement, beasts and gems,"
58290 PRINT"puzzles and quicksand.{space*2}you will lose
58300 PRINT"your way in the ever-changing jungle.
58310 PRINT"be careful!{space*2}be persistent!{space*2}but most
58320 PRINT"of all, be adventurous!{white}{down*2}"
58330 GOSUB61000
58340 RETURN
60000 PRINT"{space*40}{up}";
60001 in$="":POKE198,0:POKE204,0
60010 WAIT198,15:GETz$:z=ASC(z$):IFz>95THEN60010
60080 zl=LEN(in$):IFzl>27THEN60110
60100 IFz>31THENin$=in$+z$:PRINTz$;:GOTO60010
60110 IFz=13ANDzlTHENPOKE204,1:PRINT" ":RETURN
60120 IFz=20ANDzlTHENin$=LEFT$(in$,zl-1):PRINT" {left*2} {left}";
60140 GOTO60010
61000 FORi=1TO500:NEXT:PRINT"{down}press{cm m}{reverse on}shift{reverse off}{up}{left*5}{cm @*5}{down}{cm g}to continue";:WAIT653,1
61001 RETURN
stop tok64
(bastext 1.0)