start tok64 d64-Ik9GGY
10 REM ** programlas ** mr.p. 900324 **
20 DIMb$(255),k$(255)
30 FORi=1TO255:b$(i)=CHR$(i):k$(i)=CHR$(i):NEXT
40 FORi=128TO202:READb$(i):NEXT
50 READz,k$:IFz=0THEN70
60 k$(z)=k$:GOTO50
70 FORi=36864TO36892:READa:POKEi,a:NEXT
80 PRINT"tryck space nar bandet ar ratt spolat.":POKE198,0:WAIT198,1
90 PRINT"laddar{.*3}":SYS36864
100 INPUT"{clear}printer j/n ";d$:IFd$="j"THENOPEN2,4:CMD2
110 ad=5634:sl=PEEK(5632)+PEEK(5633)*256
120 ad=ad+2
130 REM radnummer
140 r=PEEK(ad)+256*PEEK(ad+1):ad=ad+2
150 IFad<=slTHEN190
160 IFd$="j"THENPRINT#2:CLOSE2
170 INPUT"fler program (n)";a$:IFa$="j"THEN80
180 END
190 r$=MID$(STR$(r),2)
200 PRINTr$" ";
210 x=PEEK(ad):ad=ad+1
220 IFx=34THEN290
230 IFx=0THEN250
240 PRINTb$(x);:GOTO210
250 REM radslut
260 PRINT
270 IFd$<>"j"THENPOKE198,0:WAIT198,1:POKE198,0
280 GOTO120
290 REM "
300 PRINTCHR$(34);
310 x=PEEK(ad):y=PEEK(ad+1):ad=ad+1
320 IFx=0THEN250
330 IFx=yAND(LEN(k$(x))>1ORx=32)THEN380
340 IFLEN(k$(x))>1THENPRINT"<"k$(x)">";:GOTO360
350 PRINTk$(x);
360 IFx<>34THEN310
370 x=y:z=0:ad=ad+1:GOTO230
380 c=0
390 c=c+1:y=PEEK(ad+c):IFx=yTHEN390
400 k$=k$(x):IFx=32THENk$="spaces"
410 PRINT"<"+MID$(STR$(c+1),2)+" "+k$+">";:ad=ad+c:GOTO360
420 REM basic
430 DATAend,for,next,data,input#,input,dim,read,let,goto,run,if,restore,gosub
440 DATAreturn,rem,stop,on,wait,load,save,verify,def,poke,print#,print,cont
450 DATAlist,clr,cmd,sys,open,close,get,new,tab(,to,fn,spc(,then,not,step,+,-
460 DATA*,/,{^},and,or,>,=,<,sgn,int,abs,usr,fre,pos,sqr,rnd,log,exp,cos,sin,tan
470 DATAatn,peek,len,str$,val,asc,chr$,left$,right$,mid$
480 REM specialtecken
490 DATA5,white,8,ctrl/h,9,ctrl/i,14,ctrl/n,17,down,18,rvs on,19,home,20,del
500 DATA28,red,29,right,30,green,31,blue,129,orange,133,f1,134,f3,135,f5
510 DATA136,f7,137,f2,138,f4,139,f6,140,f8,142,uppercase,144,black,145,up
520 DATA146,rvs off,147,clear,148,insert,149,brown,150,lt red,151,grey 1
530 DATA152,grey 2,153,lt green,154,lt blue,155,grey 3,156,purple,157,left
540 DATA158,yellow,159,cyan,160,shift/space,0,
550 DATA169,1,170,160,0,32,186,255
560 DATA169,0,32,189,255,169,0,162
570 DATA2,160,22,32,213,255,142,0
580 DATA22,140,1,22,96
stop tok64
(bastext 1.0)